f2026f1e34
* Create ESP_NetworkInterface class and have Ethernet extending it * Update CMakeLists.txt * Split networking from WiFi (H2 can now use Ethernet) Now all libs have been checked yet. More to do on WiFi side * Fix build errors * Guard WiFi classes and fix RMII ETH examples * Decouple network related libraries from WiFi * Fix examples and WiFiUpdate * Guard WiFiProv lib to compile only on WiFi chips * Add periman string for network and "fix" mdns on the first ETH * Revert back location of Client/Server/Udp in order to accept some PRs * Fix periman * Some fixes from merging master * Fix web server missing fs.h * Move Client, Server and Udp out of WiFi * More fixes * more fixes * Fix CMakekLists and rework lib menu dependencies * Fix CMake issues * move back WiFiClient to rebase with master * Update ETH_TLK110.ino * Move back WiFiClient * Update progress * Update WiFiGeneric.cpp * More fixes * Switch AP to the new interface * Cleanup * Rename AP methods * Add extra interface info for Printable * Rename IPv6 getters to clarify that they are returning LinkLocal address cc @sgryphon * Rename network classes cc @sgryphon * Update NetworkManager.h * Rename WiFi Server and UDP * Rename WiFiClient and WiFiClientSecure * Update CMakeLists.txt * Update on-push.sh * Rename Network library * Remove unnecessary guard * Get the correct interface MAC address for mDND Workstation service * Apply suggestions from code review Co-authored-by: Lucas Saavedra Vaz <32426024+lucasssvaz@users.noreply.github.com> --------- Co-authored-by: Lucas Saavedra Vaz <32426024+lucasssvaz@users.noreply.github.com>
133 lines
4.1 KiB
C++
133 lines
4.1 KiB
C++
#include <WiFi.h>
|
|
#include <NetworkClient.h>
|
|
#include <WebServer.h>
|
|
|
|
const char* ssid = "........";
|
|
const char* password = "........";
|
|
|
|
WebServer server(80);
|
|
|
|
//Check if header is present and correct
|
|
bool is_authentified() {
|
|
Serial.println("Enter is_authentified");
|
|
if (server.hasHeader("Cookie")) {
|
|
Serial.print("Found cookie: ");
|
|
String cookie = server.header("Cookie");
|
|
Serial.println(cookie);
|
|
if (cookie.indexOf("ESPSESSIONID=1") != -1) {
|
|
Serial.println("Authentification Successful");
|
|
return true;
|
|
}
|
|
}
|
|
Serial.println("Authentification Failed");
|
|
return false;
|
|
}
|
|
|
|
//login page, also called for disconnect
|
|
void handleLogin() {
|
|
String msg;
|
|
if (server.hasHeader("Cookie")) {
|
|
Serial.print("Found cookie: ");
|
|
String cookie = server.header("Cookie");
|
|
Serial.println(cookie);
|
|
}
|
|
if (server.hasArg("DISCONNECT")) {
|
|
Serial.println("Disconnection");
|
|
server.sendHeader("Location", "/login");
|
|
server.sendHeader("Cache-Control", "no-cache");
|
|
server.sendHeader("Set-Cookie", "ESPSESSIONID=0");
|
|
server.send(301);
|
|
return;
|
|
}
|
|
if (server.hasArg("USERNAME") && server.hasArg("PASSWORD")) {
|
|
if (server.arg("USERNAME") == "admin" && server.arg("PASSWORD") == "admin") {
|
|
server.sendHeader("Location", "/");
|
|
server.sendHeader("Cache-Control", "no-cache");
|
|
server.sendHeader("Set-Cookie", "ESPSESSIONID=1");
|
|
server.send(301);
|
|
Serial.println("Log in Successful");
|
|
return;
|
|
}
|
|
msg = "Wrong username/password! try again.";
|
|
Serial.println("Log in Failed");
|
|
}
|
|
String content = "<html><body><form action='/login' method='POST'>To log in, please use : admin/admin<br>";
|
|
content += "User:<input type='text' name='USERNAME' placeholder='user name'><br>";
|
|
content += "Password:<input type='password' name='PASSWORD' placeholder='password'><br>";
|
|
content += "<input type='submit' name='SUBMIT' value='Submit'></form>" + msg + "<br>";
|
|
content += "You also can go <a href='/inline'>here</a></body></html>";
|
|
server.send(200, "text/html", content);
|
|
}
|
|
|
|
//root page can be accessed only if authentification is ok
|
|
void handleRoot() {
|
|
Serial.println("Enter handleRoot");
|
|
String header;
|
|
if (!is_authentified()) {
|
|
server.sendHeader("Location", "/login");
|
|
server.sendHeader("Cache-Control", "no-cache");
|
|
server.send(301);
|
|
return;
|
|
}
|
|
String content = "<html><body><H2>hello, you successfully connected to esp8266!</H2><br>";
|
|
if (server.hasHeader("User-Agent")) {
|
|
content += "the user agent used is : " + server.header("User-Agent") + "<br><br>";
|
|
}
|
|
content += "You can access this page until you <a href=\"/login?DISCONNECT=YES\">disconnect</a></body></html>";
|
|
server.send(200, "text/html", content);
|
|
}
|
|
|
|
//no need authentification
|
|
void handleNotFound() {
|
|
String message = "File Not Found\n\n";
|
|
message += "URI: ";
|
|
message += server.uri();
|
|
message += "\nMethod: ";
|
|
message += (server.method() == HTTP_GET) ? "GET" : "POST";
|
|
message += "\nArguments: ";
|
|
message += server.args();
|
|
message += "\n";
|
|
for (uint8_t i = 0; i < server.args(); i++) {
|
|
message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
|
|
}
|
|
server.send(404, "text/plain", message);
|
|
}
|
|
|
|
void setup(void) {
|
|
Serial.begin(115200);
|
|
WiFi.mode(WIFI_STA);
|
|
WiFi.begin(ssid, password);
|
|
Serial.println("");
|
|
|
|
// Wait for connection
|
|
while (WiFi.status() != WL_CONNECTED) {
|
|
delay(500);
|
|
Serial.print(".");
|
|
}
|
|
Serial.println("");
|
|
Serial.print("Connected to ");
|
|
Serial.println(ssid);
|
|
Serial.print("IP address: ");
|
|
Serial.println(WiFi.localIP());
|
|
|
|
|
|
server.on("/", handleRoot);
|
|
server.on("/login", handleLogin);
|
|
server.on("/inline", []() {
|
|
server.send(200, "text/plain", "this works without need of authentification");
|
|
});
|
|
|
|
server.onNotFound(handleNotFound);
|
|
//here the list of headers to be recorded
|
|
const char * headerkeys[] = {"User-Agent", "Cookie"} ;
|
|
size_t headerkeyssize = sizeof(headerkeys) / sizeof(char*);
|
|
//ask server to track these headers
|
|
server.collectHeaders(headerkeys, headerkeyssize);
|
|
server.begin();
|
|
Serial.println("HTTP server started");
|
|
}
|
|
|
|
void loop(void) {
|
|
server.handleClient();
|
|
delay(2);//allow the cpu to switch to other tasks
|
|
}
|