SDL2_mixer and midiproc

CMakeLists.txt

@@ -3,8 +3,23 @@ set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
 cmake_minimum_required(VERSION 3.9.3)
 project("Chocolate Doom" VERSION 3.0.0 LANGUAGES C)
 
+# AC_INIT variables
+set(PACKAGE_NAME "${PROJECT_NAME}")
+set(PACKAGE_STRING "${PROJECT_NAME} ${PROJECT_VERSION}")
+
+string(REGEX REPLACE " Doom$" "" PACKAGE_SHORTNAME "${PACKAGE_NAME}")
+
 find_package(SDL2 2.0.1)
 find_package(SDL2_mixer 2.0.0)
 find_package(SDL2_net 2.0.0)
 
+# Without a hyphen. This is used for the bash-completion scripts.
+string(TOLOWER "${PACKAGE_SHORTNAME}" PROGRAM_SPREFIX)
+
+# With a hyphen, used almost everywhere else.
+set(PROGRAM_PREFIX "${PROGRAM_SPREFIX}-")
+
+configure_file(config.cmake.h config.h)
+
+add_subdirectory(midiproc)
 add_subdirectory(textscreen)

cmake/FindSDL2.cmake

@@ -1,11 +1,42 @@
+# FindSDL2.cmake
+#
+# Copyright (c) 2018, Alex Mayfield <alexmax2742@gmail.com>
+# All rights reserved.
+# 
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+#     * Redistributions of source code must retain the above copyright
+#       notice, this list of conditions and the following disclaimer.
+#     * Redistributions in binary form must reproduce the above copyright
+#       notice, this list of conditions and the following disclaimer in the
+#       documentation and/or other materials provided with the distribution.
+#     * Neither the name of the <organization> nor the
+#       names of its contributors may be used to endorse or promote products
+#       derived from this software without specific prior written permission.
+# 
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+# DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> BE LIABLE FOR ANY
+# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
+# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+#
 # Currently works with the following generators:
 # - Visual Studio
 
+# Cache variable that allows you to point CMake at a directory containing
+# an extracted development library.
 set(SDL2_DIR "${SDL2_DIR}" CACHE PATH "Location of SDL2 library directory")
 
+# Find the include directory.
 find_path(SDL2_INCLUDE_DIR "SDL_version.h"
           PATHS "${SDL2_DIR}/include")
 
+# Find the version.  Taken and modified from CMake's FindSDL.cmake.
 if(SDL2_INCLUDE_DIR AND EXISTS "${SDL2_INCLUDE_DIR}/SDL_version.h")
     file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+[0-9]+$")
     file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MINOR_VERSION[ \t]+[0-9]+$")
@@ -22,6 +53,7 @@ if(SDL2_INCLUDE_DIR AND EXISTS "${SDL2_INCLUDE_DIR}/SDL_version.h")
     unset(SDL2_VERSION_PATCH)
 endif()
 
+# Find the SDL2 and SDL2main libraries
 if(CMAKE_SIZEOF_VOID_P STREQUAL 8)
     find_library(SDL2_LIBRARY "SDL2"
                  PATHS "${SDL2_DIR}/lib/x64")
@@ -43,10 +75,13 @@ find_package_handle_standard_args(SDL2
 )
 
 if(SDL2_FOUND)
+    # SDL2 imported target.
     add_library(SDL2::SDL2 UNKNOWN IMPORTED)
     set_target_properties(SDL2::SDL2 PROPERTIES
                           INTERFACE_INCLUDE_DIRECTORIES "${SDL2_INCLUDE_DIR}"
                           IMPORTED_LOCATION "${SDL2_LIBRARY}")
+
+    # SDL2main imported target.
     add_library(SDL2::SDL2main UNKNOWN IMPORTED)
     set_target_properties(SDL2::SDL2main PROPERTIES
                           IMPORTED_LOCATION "${SDL2_MAIN_LIBRARY}")

cmake/FindSDL2_mixer.cmake

@@ -0,0 +1,79 @@
+# FindSDL2_mixer.cmake
+#
+# Copyright (c) 2018, Alex Mayfield <alexmax2742@gmail.com>
+# All rights reserved.
+# 
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+#     * Redistributions of source code must retain the above copyright
+#       notice, this list of conditions and the following disclaimer.
+#     * Redistributions in binary form must reproduce the above copyright
+#       notice, this list of conditions and the following disclaimer in the
+#       documentation and/or other materials provided with the distribution.
+#     * Neither the name of the <organization> nor the
+#       names of its contributors may be used to endorse or promote products
+#       derived from this software without specific prior written permission.
+# 
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+# DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> BE LIABLE FOR ANY
+# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
+# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+#
+# Currently works with the following generators:
+# - Visual Studio
+
+# Cache variable that allows you to point CMake at a directory containing
+# an extracted development library.
+set(SDL2_MIXER_DIR "${SDL2_MIXER_DIR}" CACHE PATH "Location of SDL2_mixer library directory")
+
+# Find the include directory.
+find_path(SDL2_MIXER_INCLUDE_DIR "SDL_mixer.h"
+          PATHS "${SDL2_MIXER_DIR}/include")
+
+# Find the version.  Taken and modified from CMake's FindSDL.cmake.
+if(SDL2_MIXER_INCLUDE_DIR AND EXISTS "${SDL2_MIXER_INCLUDE_DIR}/SDL_mixer.h")
+    file(STRINGS "${SDL2_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL2_MIXER_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MIXER_MAJOR_VERSION[ \t]+[0-9]+$")
+    file(STRINGS "${SDL2_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL2_MIXER_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MIXER_MINOR_VERSION[ \t]+[0-9]+$")
+    file(STRINGS "${SDL2_MIXER_INCLUDE_DIR}/SDL_mixer.h" SDL2_MIXER_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_MIXER_PATCHLEVEL[ \t]+[0-9]+$")
+    string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_MIXER_VERSION_MAJOR "${SDL2_MIXER_VERSION_MAJOR_LINE}")
+    string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_MIXER_VERSION_MINOR "${SDL2_MIXER_VERSION_MINOR_LINE}")
+    string(REGEX REPLACE "^#define[ \t]+SDL_MIXER_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL2_MIXER_VERSION_PATCH "${SDL2_MIXER_VERSION_PATCH_LINE}")
+    set(SDL2_MIXER_VERSION "${SDL2_MIXER_VERSION_MAJOR}.${SDL2_MIXER_VERSION_MINOR}.${SDL2_MIXER_VERSION_PATCH}")
+    unset(SDL2_MIXER_VERSION_MAJOR_LINE)
+    unset(SDL2_MIXER_VERSION_MINOR_LINE)
+    unset(SDL2_MIXER_VERSION_PATCH_LINE)
+    unset(SDL2_MIXER_VERSION_MAJOR)
+    unset(SDL2_MIXER_VERSION_MINOR)
+    unset(SDL2_MIXER_VERSION_PATCH)
+endif()
+
+# Find the library.
+if(CMAKE_SIZEOF_VOID_P STREQUAL 8)
+    find_library(SDL2_MIXER_LIBRARY "SDL2_mixer"
+                 PATHS "${SDL2_MIXER_DIR}/lib/x64")
+else()
+    find_library(SDL2_MIXER_LIBRARY "SDL2"
+                 PATHS "${SDL2_MIXER_DIR}/lib/x86")
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SDL2_mixer
+    FOUND_VAR SDL2_MIXER_FOUND
+    REQUIRED_VARS SDL2_MIXER_INCLUDE_DIR SDL2_MIXER_LIBRARY
+    VERSION_VAR SDL2_MIXER_VERSION
+)
+
+if(SDL2_MIXER_FOUND)
+    # Imported target.
+    add_library(SDL2::mixer UNKNOWN IMPORTED)
+    set_target_properties(SDL2::mixer PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${SDL2_MIXER_INCLUDE_DIR}"
+                          INTERFACE_LINK_LIBRARIES SDL2::SDL2
+                          IMPORTED_LOCATION "${SDL2_MIXER_LIBRARY}")
+endif()

config.cmake.h

@@ -0,0 +1,3 @@
+#cmakedefine PACKAGE_NAME "@PACKAGE_NAME@"
+#cmakedefine PACKAGE_STRING "@PACKAGE_STRING@"
+#cmakedefine PROGRAM_PREFIX "@PROGRAM_PREFIX@"

midiproc/CMakeLists.txt

@@ -0,0 +1,4 @@
+add_executable("${PROGRAM_PREFIX}midiproc" buffer.c buffer.h main.c proto.h)
+target_include_directories("${PROGRAM_PREFIX}midiproc"
+                           PRIVATE "../src/" "${CMAKE_CURRENT_BINARY_DIR}/../")
+target_link_libraries("${PROGRAM_PREFIX}midiproc" SDL2::SDL2main SDL2::mixer)